[Mesa-dev] [PATCH] configure.ac: Add --with-(gl|glu|osmesa)-lib-name options

[Kenneth Graunke]

On 06/05/2012 10:59 AM, Brad King wrote:
> These allow one to mangle the library names, without also mangling the
> symbol names, to make them distinct from other GL libraries on the
> system.
> ---
> 
> On 06/05/2012 01:38 PM, Kenneth Graunke wrote:
>> This looks good to me.  The only real question I have is whether it
>> makes sense to set them via environment variables, like you did, or
>> whether it'd be better to use AC_ARG_WITH and do:
>>
>> ./autogen.sh --with-gl-lib-name=GL --with-glu-lib-name=GLU
>> --with-osmesa-lib-name=OSMesa ...
> 
> That looks cleaner to me.  Here is a patch for it.
> 
> Thanks,
> -Brad
> 
>  configure.ac |   29 ++++++++++++++++++++++-------
>  1 file changed, 22 insertions(+), 7 deletions(-)
> 
> diff --git a/configure.ac b/configure.ac
> index 9fb8149..e607d1c 100644
> --- a/configure.ac
> +++ b/configure.ac
> @@ -355,6 +355,24 @@ else
>          LIB_EXTENSION='so' ;;
>      esac
>  fi
> +AC_ARG_WITH([gl-lib-name],
> +  [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
> +    [specify GL library name @<:@default=GL@:>@])],
> +  [GL_LIB=$withval],
> +  [GL_LIB=GL])
> +AC_ARG_WITH([glu-lib-name],
> +  [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
> +    [specify GLU library name @<:@default=GLU@:>@])],
> +  [GLU_LIB=$withval],
> +  [GLU_LIB=GLU])
> +AC_ARG_WITH([osmesa-lib-name],
> +  [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
> +    [specify OSMesa library name @<:@default=OSMesa@:>@])],
> +  [OSMESA_LIB=$withval],
> +  [OSMESA_LIB=OSMesa])
> +AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
> +AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
> +AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
>  
>  dnl
>  dnl Mangled Mesa support
> @@ -365,19 +383,16 @@ AC_ARG_ENABLE([mangling],
>    [enable_mangling="${enableval}"],
>    [enable_mangling=no]
>  )
> -GL_LIB="GL"
> -GLU_LIB="GLU"
> -OSMESA_LIB="OSMesa"
>  if test "x${enable_mangling}" = "xyes" ; then
>    DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
> -  GL_LIB="MangledGL"
> -  GLU_LIB="MangledGLU"
> -  OSMESA_LIB="MangledOSMesa"
> +  GL_LIB="Mangled${GL_LIB}"
> +  GLU_LIB="Mangled${GLU_LIB}"
> +  OSMESA_LIB="Mangled${OSMESA_LIB}"
>  fi
>  AC_SUBST([GL_LIB])
>  AC_SUBST([GLU_LIB])
>  AC_SUBST([OSMESA_LIB])
> -AM_CONDITIONAL(HAVE_MANGLED_GL, test $GL_LIB = MangledGL)
> +AM_CONDITIONAL(HAVE_MANGLED_GL, test "x${enable_mangling}" = "xyes")
>  
>  dnl
>  dnl potentially-infringing-but-nobody-knows-for-sure stuff

Reviewed-by: Kenneth Graunke <kenneth at whitecape.org>

If there are no objections, I'll push this tomorrow.  Thanks!