[Piglit] [PATCH 05/13 v2] arb_shader_storage_buffer: Add test for atomicCompSwap(int, int, int)

[Ian Romanick]

From: Ian Romanick <ian.d.romanick at intel.com>

v2: Use gl_SampleMaskIn to detect helper invocations.  Suggested by
issue #22 of the GL_ARB_shader_image_load_store spec.

Signed-off-by: Ian Romanick <ian.d.romanick at intel.com>
---
 .../execution/ssbo-atomicCompSwap-int.shader_test  | 84 ++++++++++++++++++++++
 1 file changed, 84 insertions(+)
 create mode 100644 tests/spec/arb_shader_storage_buffer_object/execution/ssbo-atomicCompSwap-int.shader_test

diff --git a/tests/spec/arb_shader_storage_buffer_object/execution/ssbo-atomicCompSwap-int.shader_test b/tests/spec/arb_shader_storage_buffer_object/execution/ssbo-atomicCompSwap-int.shader_test
new file mode 100644
index 000000000..30990054c
--- /dev/null
+++ b/tests/spec/arb_shader_storage_buffer_object/execution/ssbo-atomicCompSwap-int.shader_test
@@ -0,0 +1,84 @@
+[require]
+GL >= 3.3
+GLSL >= 3.30
+GL_ARB_shader_storage_buffer_object
+GL_ARB_shader_atomic_counters
+GL_ARB_shader_atomic_counter_ops
+GL_ARB_gpu_shader5
+
+[vertex shader passthrough]
+
+[fragment shader]
+#extension GL_ARB_shader_storage_buffer_object: require
+#extension GL_ARB_shader_atomic_counters: require
+#extension GL_ARB_shader_atomic_counter_ops: require
+#extension GL_ARB_gpu_shader5: require
+
+layout(binding = 0) buffer bufblock {
+	int value;
+};
+
+/* GL_ARB_shader_atomic_counters requires at least 8 total counters. */
+layout(binding = 0) uniform atomic_uint mask[7];
+layout(binding = 0) uniform atomic_uint fail;
+
+out vec4 color;
+
+void main()
+{
+	/* According to issue #22 of the GL_ARB_shader_image_load_store, the
+	 * return result of atomic operations in helper invocations is
+	 * undefined.  To avoid a possible infinite loop (below) in a helper
+	 * invocation, bail out now.
+	 */
+	if (gl_SampleMaskIn[0] == 0)
+		return;
+
+	/* Each of 32 * N fragments should see a unique value.  Each value
+	 * observed is tracked in "mask."  The test automatically fails if a
+	 * duplicate value is observed.  After the shaders are done running,
+	 * the mask values will be probed to ensure that all possible values
+	 * were observed.
+	 */
+	int f;
+
+	/* This is an open-coded atomicAdd. */
+	do {
+		f = value;
+	} while (f != atomicCompSwap(value, f, f + 4));
+
+	uint i = uint(f) / 4u;
+	uint bit = i % 32u;
+	int c = int(i / 32u);
+	uint m = 1u << bit;
+
+	if (c < mask.length()) {
+		/* If the bit was already set, the test fails. */
+		if ((atomicCounterOrARB(mask[c], m) & m) != 0u)
+			atomicCounterIncrement(fail);
+
+		color = vec4(0.0, 1.0, 0.0, 1.0);
+	} else {
+		color = vec4(0.0, 0.0, 1.0, 1.0);
+	}
+}
+
+[test]
+atomic counters 8
+
+ssbo 0 32
+ssbo 0 subdata float 0 0.0
+
+clear color 0.5 0.5 0.5 0.5
+clear
+
+draw rect -1 -1 2 2
+
+probe atomic counter 0 == 4294967295
+probe atomic counter 1 == 4294967295
+probe atomic counter 2 == 4294967295
+probe atomic counter 3 == 4294967295
+probe atomic counter 4 == 4294967295
+probe atomic counter 5 == 4294967295
+probe atomic counter 6 == 4294967295
+probe atomic counter 7 == 0
-- 
2.14.4