[Piglit] [PATCH 4/7] intel_shader_atomic_float_minmax: Add tests for atomicCompSwap(float, float, float)

[Ian Romanick]

From: Ian Romanick <ian.d.romanick at intel.com>

This test is similar to the NV_shader_atomic_float test for atomicAdd.
Instead of using atomicAdd, it uses a loop with atomicCompSwap to
open-code it.

Signed-off-by: Ian Romanick <ian.d.romanick at intel.com>
---
 .../shared-atomicCompSwap-float.shader_test        | 66 +++++++++++++++++
 .../ssbo-atomicCompSwap-float.shader_test          | 86 ++++++++++++++++++++++
 2 files changed, 152 insertions(+)
 create mode 100644 tests/spec/intel_shader_atomic_float_minmax/execution/shared-atomicCompSwap-float.shader_test
 create mode 100644 tests/spec/intel_shader_atomic_float_minmax/execution/ssbo-atomicCompSwap-float.shader_test

diff --git a/tests/spec/intel_shader_atomic_float_minmax/execution/shared-atomicCompSwap-float.shader_test b/tests/spec/intel_shader_atomic_float_minmax/execution/shared-atomicCompSwap-float.shader_test
new file mode 100644
index 000000000..2b38f0d12
--- /dev/null
+++ b/tests/spec/intel_shader_atomic_float_minmax/execution/shared-atomicCompSwap-float.shader_test
@@ -0,0 +1,66 @@
+[require]
+GL >= 3.3
+GLSL >= 3.30
+GL_ARB_compute_shader
+GL_ARB_shader_atomic_counters
+GL_INTEL_shader_atomic_float_minmax
+
+[compute shader]
+#version 330
+#extension GL_ARB_compute_shader: require
+#extension GL_ARB_shader_atomic_counters: require
+#extension GL_INTEL_shader_atomic_float_minmax: require
+
+layout(local_size_x = 32) in;
+
+shared float value;
+shared uint mask;
+
+layout(binding = 0) uniform atomic_uint pass;
+layout(binding = 0) uniform atomic_uint fail;
+
+void main()
+{
+	if (gl_LocalInvocationIndex == 0u) {
+		value = 0.0;
+		mask = 0u;
+	}
+
+	barrier();
+
+	/* Each local invocation should see a unique value.  Each value
+	 * observed is tracked in "mask."  The test automatically fails if a
+	 * duplicate value is observed.  The test passes once all 32 possible
+	 * values have been observed.
+	 */
+	float f = value;
+	float a;
+
+	/* This is an open-coded atomicAdd. */
+	do {
+		a = f;
+	} while ((f = atomicCompSwap(value, f, f + .5)) != a);
+
+	uint i = uint(f * 2.0);
+	uint bit = i % 32u;
+	uint m = 1u << bit;
+
+	if (i < 32u) {
+		/* If the bit was already set, the test fails. */
+		uint r = atomicOr(mask, m);
+		if ((r & m) != 0u)
+			atomicCounterIncrement(fail);
+
+		/* Once all 32 bits are set, the test passes. */
+		if ((r | m) == 0xffffffffu)
+			atomicCounterIncrement(pass);
+	} else {
+		atomicCounterIncrement(fail);
+	}
+}
+
+[test]
+atomic counters 2
+compute 2 3 4
+probe atomic counter 0 == 24
+probe atomic counter 1 == 0
diff --git a/tests/spec/intel_shader_atomic_float_minmax/execution/ssbo-atomicCompSwap-float.shader_test b/tests/spec/intel_shader_atomic_float_minmax/execution/ssbo-atomicCompSwap-float.shader_test
new file mode 100644
index 000000000..008d067aa
--- /dev/null
+++ b/tests/spec/intel_shader_atomic_float_minmax/execution/ssbo-atomicCompSwap-float.shader_test
@@ -0,0 +1,86 @@
+[require]
+GL >= 3.3
+GLSL >= 3.30
+GL_ARB_shader_storage_buffer_object
+GL_ARB_shader_atomic_counters
+GL_ARB_shader_atomic_counter_ops
+GL_ARB_gpu_shader5
+GL_INTEL_shader_atomic_float_minmax
+
+[vertex shader passthrough]
+
+[fragment shader]
+#extension GL_ARB_shader_storage_buffer_object: require
+#extension GL_ARB_shader_atomic_counters: require
+#extension GL_ARB_shader_atomic_counter_ops: require
+#extension GL_ARB_gpu_shader5: require
+#extension GL_INTEL_shader_atomic_float_minmax: require
+
+layout(binding = 0) buffer bufblock {
+	float value;
+};
+
+/* GL_ARB_shader_atomic_counters requires at least 8 total counters. */
+layout(binding = 0) uniform atomic_uint mask[7];
+layout(binding = 0) uniform atomic_uint fail;
+
+out vec4 color;
+
+void main()
+{
+	/* According to issue #22 of the GL_ARB_shader_image_load_store, the
+	 * return result of atomic operations in helper invocations is
+	 * undefined.  To avoid a possible infinite loop (below) in a helper
+	 * invocation, bail out now.
+	 */
+	if (gl_SampleMaskIn[0] == 0)
+		return;
+
+	/* Each of 32 * N fragments should see a unique value.  Each value
+	 * observed is tracked in "mask."  The test automatically fails if a
+	 * duplicate value is observed.  After the shaders are done running,
+	 * the mask values will be probed to ensure that all possible values
+	 * were observed.
+	 */
+	float f;
+
+	/* This is an open-coded atomicAdd. */
+	do {
+		f = value;
+	} while (f != atomicCompSwap(value, f, f + .5));
+
+	uint i = uint(f * 2.0);
+	uint bit = i % 32u;
+	int c = int(i / 32u);
+	uint m = 1u << bit;
+
+	if (c < mask.length()) {
+		/* If the bit was already set, the test fails. */
+		if ((atomicCounterOrARB(mask[c], m) & m) != 0u)
+			atomicCounterIncrement(fail);
+
+		color = vec4(0.0, 1.0, 0.0, 1.0);
+	} else {
+		color = vec4(0.0, 0.0, 1.0, 1.0);
+	}
+}
+
+[test]
+atomic counters 8
+
+ssbo 0 32
+ssbo 0 subdata float 0 0.0
+
+clear color 0.5 0.5 0.5 0.5
+clear
+
+draw rect -1 -1 2 2
+
+probe atomic counter 0 == 4294967295
+probe atomic counter 1 == 4294967295
+probe atomic counter 2 == 4294967295
+probe atomic counter 3 == 4294967295
+probe atomic counter 4 == 4294967295
+probe atomic counter 5 == 4294967295
+probe atomic counter 6 == 4294967295
+probe atomic counter 7 == 0
-- 
2.14.4