[Spice-commits] 11 commits - common/Makefile.am configure.ac m4/spice-deps.m4
Christophe Fergau
teuf at kemper.freedesktop.org
Mon Dec 15 02:45:12 PST 2014
common/Makefile.am | 13 +---
configure.ac | 112 ++++-------------------------------------
m4/spice-deps.m4 | 143 +++++++++++++++++++++++++++++++++++++++++++++++++++++
3 files changed, 159 insertions(+), 109 deletions(-)
New commits:
commit 862b9b1a9e39b2448768417e05c436466c060423
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 14:52:51 2014 +0100
build-sys: Move pixman check to m4 macro
diff --git a/common/Makefile.am b/common/Makefile.am
index 5a689fe..b4384e8 100644
--- a/common/Makefile.am
+++ b/common/Makefile.am
@@ -92,7 +92,6 @@ endif
AM_CPPFLAGS = \
-I$(top_srcdir) \
$(SPICE_COMMON_CFLAGS) \
- $(PIXMAN_CFLAGS) \
$(PROTOCOL_CFLAGS) \
$(NULL)
diff --git a/configure.ac b/configure.ac
index ff0e34c..32d4c4d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -36,9 +36,7 @@ AC_CONFIG_SUBDIRS([spice-protocol])
PROTOCOL_CFLAGS='-I ${top_srcdir}/spice-protocol'
AC_SUBST(PROTOCOL_CFLAGS)
-PKG_CHECK_MODULES(PIXMAN, pixman-1 >= 0.17.7)
-AC_SUBST(PIXMAN_CFLAGS)
-
+SPICE_CHECK_PIXMAN(SPICE_COMMON)
SPICE_CHECK_SMARTCARD(SPICE_COMMON)
SPICE_CHECK_CELT051(SPICE_COMMON)
SPICE_CHECK_OPUS(SPICE_COMMON)
diff --git a/m4/spice-deps.m4 b/m4/spice-deps.m4
index b891aef..0815766 100644
--- a/m4/spice-deps.m4
+++ b/m4/spice-deps.m4
@@ -129,3 +129,15 @@ AC_DEFUN([SPICE_CHECK_OPENGL], [
AS_VAR_APPEND([$1_CFLAGS], [" $GL_CFLAGS"])
AS_VAR_APPEND([$1_LIBS], [" $GL_LIBS"])
])
+
+
+# SPICE_CHECK_PIXMAN(PREFIX)
+# --------------------------
+# Check for the availability of pixman. If found, it will append the flags to
+# use to the $PREFIX_CFLAGS and $PREFIX_LIBS variables.
+#---------------------------
+AC_DEFUN([SPICE_CHECK_PIXMAN], [
+ PKG_CHECK_MODULES(PIXMAN, pixman-1 >= 0.17.7)
+ AS_VAR_APPEND([$1_CFLAGS], [" $PIXMAN_CFLAGS"])
+ AS_VAR_APPEND([$1_LIBS], [" $PIXMAN_LIBS"])
+])
commit 137b1a549e0d97b7f82a5f62be91864319fc2ad9
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 11:38:11 2014 +0100
build-sys: Move opengl check to m4 macro
diff --git a/common/Makefile.am b/common/Makefile.am
index c5e2e2a..5a689fe 100644
--- a/common/Makefile.am
+++ b/common/Makefile.am
@@ -92,7 +92,6 @@ endif
AM_CPPFLAGS = \
-I$(top_srcdir) \
$(SPICE_COMMON_CFLAGS) \
- $(GL_CFLAGS) \
$(PIXMAN_CFLAGS) \
$(PROTOCOL_CFLAGS) \
$(NULL)
diff --git a/configure.ac b/configure.ac
index d3c318a..ff0e34c 100644
--- a/configure.ac
+++ b/configure.ac
@@ -42,29 +42,10 @@ AC_SUBST(PIXMAN_CFLAGS)
SPICE_CHECK_SMARTCARD(SPICE_COMMON)
SPICE_CHECK_CELT051(SPICE_COMMON)
SPICE_CHECK_OPUS(SPICE_COMMON)
+SPICE_CHECK_OPENGL(SPICE_COMMON)
AC_SUBST(SPICE_COMMON_CFLAGS)
AC_SUBST(SPICE_COMMON_LIBS)
-AC_ARG_ENABLE([opengl],
- AS_HELP_STRING([--enable-opengl=@<:@yes/no@:>@],
- [Enable opengl support (not recommended) @<:@default=no@:>@]),
- [],
- [enable_opengl="no"])
-AM_CONDITIONAL(SUPPORT_GL, test "x$enable_opengl" = "xyes")
-
-if test "x$enable_opengl" = "xyes"; then
- AC_CHECK_LIB(GL, glBlendFunc, GL_LIBS="$GL_LIBS -lGL", enable_opengl=no)
- AC_CHECK_LIB(GLU, gluSphere, GL_LIBS="$GL_LIBS -lGLU", enable_opengl=no)
- AC_DEFINE([USE_OPENGL], [1], [Define to build with OpenGL support])
- AC_DEFINE([GL_GLEXT_PROTOTYPES], [], [Enable GLExt prototypes])
-
- if test "x$enable_opengl" = "xno"; then
- AC_MSG_ERROR([GL libraries not available])
- fi
-fi
-AC_SUBST(GL_CFLAGS)
-AC_SUBST(GL_LIBS)
-
# The End!
AC_CONFIG_FILES([
Makefile
diff --git a/m4/spice-deps.m4 b/m4/spice-deps.m4
index 6816e23..b891aef 100644
--- a/m4/spice-deps.m4
+++ b/m4/spice-deps.m4
@@ -98,3 +98,34 @@ AC_DEFUN([SPICE_CHECK_OPUS], [
AS_VAR_APPEND([$1_CFLAGS], [" $OPUS_CFLAGS"])
AS_VAR_APPEND([$1_LIBS], [" $OPUS_LIBS"])
])
+
+
+# SPICE_CHECK_OPENGL(PREFIX)
+# --------------------------
+# Adds a --disable-opengl switch in order to enable/disable OpenGL
+# support, and checks if the needed libraries are available. If found, it will
+# append the flags to use to the $PREFIX_CFLAGS and $PREFIX_LIBS variables, and
+# it will define USE_OPENGL and GL_GLEXT_PROTOTYPES preprocessor symbol as well
+# as a SUPPORT_GL Makefile conditional.
+#---------------------------
+AC_DEFUN([SPICE_CHECK_OPENGL], [
+ AC_ARG_ENABLE([opengl],
+ AS_HELP_STRING([--enable-opengl=@<:@yes/no@:>@],
+ [Enable opengl support (not recommended) @<:@default=no@:>@]),
+ [],
+ [enable_opengl="no"])
+ AM_CONDITIONAL(SUPPORT_GL, test "x$enable_opengl" = "xyes")
+
+ if test "x$enable_opengl" = "xyes"; then
+ AC_CHECK_LIB(GL, glBlendFunc, GL_LIBS="$GL_LIBS -lGL", enable_opengl=no)
+ AC_CHECK_LIB(GLU, gluSphere, GL_LIBS="$GL_LIBS -lGLU", enable_opengl=no)
+ AC_DEFINE([USE_OPENGL], [1], [Define to build with OpenGL support])
+ AC_DEFINE([GL_GLEXT_PROTOTYPES], [], [Enable GLExt prototypes])
+
+ if test "x$enable_opengl" = "xno"; then
+ AC_MSG_ERROR([GL libraries not available])
+ fi
+ fi
+ AS_VAR_APPEND([$1_CFLAGS], [" $GL_CFLAGS"])
+ AS_VAR_APPEND([$1_LIBS], [" $GL_LIBS"])
+])
commit f9e0a644aebb6cb6caa2c624f9afd2835ab6834f
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 11:31:47 2014 +0100
build-sys: Move opus check to m4 macro
diff --git a/common/Makefile.am b/common/Makefile.am
index 362fce6..c5e2e2a 100644
--- a/common/Makefile.am
+++ b/common/Makefile.am
@@ -94,13 +94,12 @@ AM_CPPFLAGS = \
$(SPICE_COMMON_CFLAGS) \
$(GL_CFLAGS) \
$(PIXMAN_CFLAGS) \
- $(OPUS_CFLAGS) \
$(PROTOCOL_CFLAGS) \
$(NULL)
libspice_common_la_LIBADD = \
$(SPICE_COMMON_LIBS) \
- $(OPUS_LIBS)
+ $(NULL)
MARSHALLERS_DEPS = \
$(top_srcdir)/python_modules/__init__.py \
diff --git a/configure.ac b/configure.ac
index 93ffc76..d3c318a 100644
--- a/configure.ac
+++ b/configure.ac
@@ -41,13 +41,10 @@ AC_SUBST(PIXMAN_CFLAGS)
SPICE_CHECK_SMARTCARD(SPICE_COMMON)
SPICE_CHECK_CELT051(SPICE_COMMON)
+SPICE_CHECK_OPUS(SPICE_COMMON)
AC_SUBST(SPICE_COMMON_CFLAGS)
AC_SUBST(SPICE_COMMON_LIBS)
-PKG_CHECK_MODULES([OPUS], [opus >= 0.9.14], have_opus=yes, have_opus=no)
-AM_CONDITIONAL([HAVE_OPUS], [test "x$have_opus" = "xyes"])
-AM_COND_IF([HAVE_OPUS], AC_DEFINE([HAVE_OPUS], 1, [Define if we have Opus]))
-
AC_ARG_ENABLE([opengl],
AS_HELP_STRING([--enable-opengl=@<:@yes/no@:>@],
[Enable opengl support (not recommended) @<:@default=no@:>@]),
diff --git a/m4/spice-deps.m4 b/m4/spice-deps.m4
index 443718b..6816e23 100644
--- a/m4/spice-deps.m4
+++ b/m4/spice-deps.m4
@@ -80,3 +80,21 @@ AC_DEFUN([SPICE_CHECK_CELT051], [
AS_VAR_APPEND([$1_CFLAGS], [" $CELT051_CFLAGS"])
AS_VAR_APPEND([$1_LIBS], [" $CELT051_LIBS"])
])
+
+
+# SPICE_CHECK_OPUS(PREFIX)
+# ------------------------
+# Check for the availability of Opus. If found, it will append the flags to use
+# to the $PREFIX_CFLAGS and $PREFIX_LIBS variables, and it will define a
+# HAVE_OPUS preprocessor symbol as well as a HAVE_OPUS Makefile conditional.
+#-------------------------
+AC_DEFUN([SPICE_CHECK_OPUS], [
+ PKG_CHECK_MODULES([OPUS], [opus >= 0.9.14], [have_opus=yes], [have_opus=no])
+
+ AM_CONDITIONAL([HAVE_OPUS], [test "x$have_opus" = "xyes"])
+ if test "x$have_opus" = "xyes" ; then
+ AC_DEFINE([HAVE_OPUS], [1], [Define if we have OPUS])
+ fi
+ AS_VAR_APPEND([$1_CFLAGS], [" $OPUS_CFLAGS"])
+ AS_VAR_APPEND([$1_LIBS], [" $OPUS_LIBS"])
+])
commit dd57d05a523746af54557e4cf5a9768ebe029d77
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 11:31:27 2014 +0100
build-sys: Move celt check to m4 macro
diff --git a/common/Makefile.am b/common/Makefile.am
index cbb8f8b..362fce6 100644
--- a/common/Makefile.am
+++ b/common/Makefile.am
@@ -94,15 +94,13 @@ AM_CPPFLAGS = \
$(SPICE_COMMON_CFLAGS) \
$(GL_CFLAGS) \
$(PIXMAN_CFLAGS) \
- $(CELT051_CFLAGS) \
$(OPUS_CFLAGS) \
$(PROTOCOL_CFLAGS) \
$(NULL)
libspice_common_la_LIBADD = \
$(SPICE_COMMON_LIBS) \
- $(OPUS_LIBS) \
- $(CELT051_LIBS)
+ $(OPUS_LIBS)
MARSHALLERS_DEPS = \
$(top_srcdir)/python_modules/__init__.py \
diff --git a/configure.ac b/configure.ac
index 27893cc..93ffc76 100644
--- a/configure.ac
+++ b/configure.ac
@@ -40,25 +40,10 @@ PKG_CHECK_MODULES(PIXMAN, pixman-1 >= 0.17.7)
AC_SUBST(PIXMAN_CFLAGS)
SPICE_CHECK_SMARTCARD(SPICE_COMMON)
+SPICE_CHECK_CELT051(SPICE_COMMON)
AC_SUBST(SPICE_COMMON_CFLAGS)
AC_SUBST(SPICE_COMMON_LIBS)
-AC_ARG_ENABLE(celt051,
-[ --disable-celt051 Disable celt051 audio codec (enabled by default)],,
-[enable_celt051="yes"])
-
-if test "x$enable_celt051" = "xyes"; then
- PKG_CHECK_MODULES(CELT051, celt051 >= 0.5.1.1, have_celt051=yes, have_celt051=no)
- AC_SUBST(CELT051_CFLAGS)
- AC_SUBST(CELT051_LIBS)
- AC_SUBST(CELT051_LIBDIR)
-else
- have_celt051=no
-fi
-
-AM_CONDITIONAL([HAVE_CELT051], [test "x$have_celt051" = "xyes"])
-AM_COND_IF([HAVE_CELT051], AC_DEFINE([HAVE_CELT051], 1, [Define if we have celt051 codec]))
-
PKG_CHECK_MODULES([OPUS], [opus >= 0.9.14], have_opus=yes, have_opus=no)
AM_CONDITIONAL([HAVE_OPUS], [test "x$have_opus" = "xyes"])
AM_COND_IF([HAVE_OPUS], AC_DEFINE([HAVE_OPUS], 1, [Define if we have Opus]))
diff --git a/m4/spice-deps.m4 b/m4/spice-deps.m4
index f5bf05f..443718b 100644
--- a/m4/spice-deps.m4
+++ b/m4/spice-deps.m4
@@ -54,3 +54,29 @@ AC_DEFUN([SPICE_CHECK_SMARTCARD], [
AS_VAR_APPEND([$1_CFLAGS], [" $SMARTCARD_CFLAGS"])
AS_VAR_APPEND([$1_LIBS], [" $SMARTCARD_LIBS"])
])
+
+
+# SPICE_CHECK_CELT051(PREFIX)
+# ---------------------------
+# Adds a --disable-celt051 switch in order to enable/disable CELT 0.5.1
+# support, and checks if the needed libraries are available. If found, it will
+# append the flags to use to the $PREFIX_CFLAGS and $PREFIX_LIBS variables, and
+# it will define a HAVE_CELT051 preprocessor symbol as well as a HAVE_CELT051
+# Makefile conditional.
+#----------------------------
+AC_DEFUN([SPICE_CHECK_CELT051], [
+ AC_ARG_ENABLE([celt051],
+ [ --disable-celt051 Disable celt051 audio codec (enabled by default)],,
+ [enable_celt051="yes"])
+
+ if test "x$enable_celt051" = "xyes"; then
+ PKG_CHECK_MODULES([CELT051], [celt051 >= 0.5.1.1], [have_celt051=yes], [have_celt051=no])
+ else
+ have_celt051=no
+ fi
+
+ AM_CONDITIONAL([HAVE_CELT051], [test "x$have_celt051" = "xyes"])
+ AM_COND_IF([HAVE_CELT051], AC_DEFINE([HAVE_CELT051], 1, [Define if we have celt051 codec]))
+ AS_VAR_APPEND([$1_CFLAGS], [" $CELT051_CFLAGS"])
+ AS_VAR_APPEND([$1_LIBS], [" $CELT051_LIBS"])
+])
commit fb3fe2272cf6fa27642593f79b351802787319d4
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Mon Dec 8 18:26:14 2014 +0100
build-sys: Move smartcard check to m4 macro
diff --git a/common/Makefile.am b/common/Makefile.am
index 2c82adc..cbb8f8b 100644
--- a/common/Makefile.am
+++ b/common/Makefile.am
@@ -91,15 +91,16 @@ endif
AM_CPPFLAGS = \
-I$(top_srcdir) \
+ $(SPICE_COMMON_CFLAGS) \
$(GL_CFLAGS) \
$(PIXMAN_CFLAGS) \
$(CELT051_CFLAGS) \
$(OPUS_CFLAGS) \
$(PROTOCOL_CFLAGS) \
- $(SMARTCARD_CFLAGS) \
$(NULL)
libspice_common_la_LIBADD = \
+ $(SPICE_COMMON_LIBS) \
$(OPUS_LIBS) \
$(CELT051_LIBS)
diff --git a/configure.ac b/configure.ac
index 67e485e..27893cc 100644
--- a/configure.ac
+++ b/configure.ac
@@ -39,22 +39,9 @@ AC_SUBST(PROTOCOL_CFLAGS)
PKG_CHECK_MODULES(PIXMAN, pixman-1 >= 0.17.7)
AC_SUBST(PIXMAN_CFLAGS)
-AC_ARG_ENABLE([smartcard],
- AS_HELP_STRING([--enable-smartcard=@<:@yes/no/auto@:>@],
- [Enable smartcard support @<:@default=auto@:>@]),
- [],
- [enable_smartcard="auto"])
-
-have_smartcard=no
-if test "x$enable_smartcard" != "xno"; then
- PKG_CHECK_MODULES(SMARTCARD, libcacard >= 0.1.2, [have_smartcard=yes], [have_smartcard=no])
- if test "x$enable_smartcard" != "xauto" && test "x$have_smartcard" = "xno"; then
- AC_MSG_ERROR("Smartcard support requested but libcacard could not be found")
- fi
- if test "x$have_smartcard" = "xyes"; then
- AC_DEFINE(USE_SMARTCARD, [1], [Define if supporting smartcard proxying])
- fi
-fi
+SPICE_CHECK_SMARTCARD(SPICE_COMMON)
+AC_SUBST(SPICE_COMMON_CFLAGS)
+AC_SUBST(SPICE_COMMON_LIBS)
AC_ARG_ENABLE(celt051,
[ --disable-celt051 Disable celt051 audio codec (enabled by default)],,
diff --git a/m4/spice-deps.m4 b/m4/spice-deps.m4
index 3dcc4b0..f5bf05f 100644
--- a/m4/spice-deps.m4
+++ b/m4/spice-deps.m4
@@ -25,3 +25,32 @@ AC_DEFUN([SPICE_CHECK_SYSDEPS], [
AC_FUNC_FORK
AC_CHECK_FUNCS([dup2 floor inet_ntoa memmove memset pow sqrt])
])
+
+
+# SPICE_CHECK_SMARTCARD(PREFIX)
+# -----------------------------
+# Adds a --enable-smartcard switch in order to enable/disable smartcard
+# support, and checks if the needed libraries are available. If found, it will
+# append the flags to use to the $PREFIX_CFLAGS and $PREFIX_LIBS variables, and
+# it will define a USE_SMARTCARD preprocessor symbol.
+#------------------------------
+AC_DEFUN([SPICE_CHECK_SMARTCARD], [
+ AC_ARG_ENABLE([smartcard],
+ AS_HELP_STRING([--enable-smartcard=@<:@yes/no/auto@:>@],
+ [Enable smartcard support @<:@default=auto@:>@]),
+ [],
+ [enable_smartcard="auto"])
+
+ have_smartcard=no
+ if test "x$enable_smartcard" != "xno"; then
+ PKG_CHECK_MODULES([SMARTCARD], [libcacard >= 0.1.2], [have_smartcard=yes], [have_smartcard=no])
+ if test "x$enable_smartcard" != "xauto" && test "x$have_smartcard" = "xno"; then
+ AC_MSG_ERROR("Smartcard support requested but libcacard could not be found")
+ fi
+ if test "x$have_smartcard" = "xyes"; then
+ AC_DEFINE(USE_SMARTCARD, [1], [Define if supporting smartcard proxying])
+ fi
+ fi
+ AS_VAR_APPEND([$1_CFLAGS], [" $SMARTCARD_CFLAGS"])
+ AS_VAR_APPEND([$1_LIBS], [" $SMARTCARD_LIBS"])
+])
commit df74a17238e376b00cbafe7a48e8e4b406095755
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 11:00:20 2014 +0100
build-sys: Move posix checks to a separate m4 macro
diff --git a/configure.ac b/configure.ac
index a58fcd6..67e485e 100644
--- a/configure.ac
+++ b/configure.ac
@@ -29,6 +29,8 @@ if test "x$ac_cv_prog_cc_c99" = xno; then
fi
AM_PROG_CC_C_O
+SPICE_CHECK_SYSDEPS
+
# Checks for libraries
AC_CONFIG_SUBDIRS([spice-protocol])
PROTOCOL_CFLAGS='-I ${top_srcdir}/spice-protocol'
@@ -94,29 +96,6 @@ fi
AC_SUBST(GL_CFLAGS)
AC_SUBST(GL_LIBS)
-# Checks for header files
-AC_FUNC_ALLOCA
-AC_CHECK_HEADERS([arpa/inet.h malloc.h netinet/in.h stddef.h stdint.h stdlib.h string.h sys/socket.h unistd.h])
-
-# Checks for typedefs, structures, and compiler characteristics
-AC_C_INLINE
-AC_TYPE_INT16_T
-AC_TYPE_INT32_T
-AC_TYPE_INT64_T
-AC_TYPE_INT8_T
-AC_TYPE_PID_T
-AC_TYPE_SIZE_T
-AC_TYPE_UINT16_T
-AC_TYPE_UINT32_T
-AC_TYPE_UINT64_T
-AC_TYPE_UINT8_T
-
-# Checks for library functions
-# do not check malloc or realloc, since that cannot be cross-compiled checked
-AC_FUNC_ERROR_AT_LINE
-AC_FUNC_FORK
-AC_CHECK_FUNCS([dup2 floor inet_ntoa memmove memset pow sqrt])
-
# The End!
AC_CONFIG_FILES([
Makefile
diff --git a/m4/spice-deps.m4 b/m4/spice-deps.m4
new file mode 100644
index 0000000..3dcc4b0
--- /dev/null
+++ b/m4/spice-deps.m4
@@ -0,0 +1,27 @@
+# SPICE_CHECK_SYSDEPS()
+# ---------------------
+# Checks for header files and library functions needed by spice-common.
+# ---------------------
+AC_DEFUN([SPICE_CHECK_SYSDEPS], [
+ AC_FUNC_ALLOCA
+ AC_CHECK_HEADERS([arpa/inet.h malloc.h netinet/in.h stddef.h stdint.h stdlib.h string.h sys/socket.h unistd.h])
+
+ # Checks for typedefs, structures, and compiler characteristics
+ AC_C_INLINE
+ AC_TYPE_INT16_T
+ AC_TYPE_INT32_T
+ AC_TYPE_INT64_T
+ AC_TYPE_INT8_T
+ AC_TYPE_PID_T
+ AC_TYPE_SIZE_T
+ AC_TYPE_UINT16_T
+ AC_TYPE_UINT32_T
+ AC_TYPE_UINT64_T
+ AC_TYPE_UINT8_T
+
+ # Checks for library functions
+ # do not check malloc or realloc, since that cannot be cross-compiled checked
+ AC_FUNC_ERROR_AT_LINE
+ AC_FUNC_FORK
+ AC_CHECK_FUNCS([dup2 floor inet_ntoa memmove memset pow sqrt])
+])
commit 2f1ba3b77f07f23ebbf0ad576985613331e4c3e4
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Wed Dec 3 16:51:13 2014 +0100
build-sys: Add fallback for AS_VAR_APPEND
This macro is not available with RHEL6 autoconf.
diff --git a/configure.ac b/configure.ac
index 8613833..a58fcd6 100644
--- a/configure.ac
+++ b/configure.ac
@@ -12,6 +12,10 @@ AC_CONFIG_AUX_DIR([build-aux])
# For automake >= 1.12
m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
+# For autoconf <= 2.63
+m4_ifndef([AS_VAR_APPEND],
+ AC_DEFUN([AS_VAR_APPEND], $1=$$1$2))
+
# Checks for programs
AM_INIT_AUTOMAKE([1.11 dist-xz no-dist-gzip tar-ustar foreign -Wall -Werror])
AM_MAINTAINER_MODE
commit 21953693727fa324cf2d038f302b5359b2ff476f
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Wed Dec 3 12:01:10 2014 +0100
build-sys: Small cleanup of AM_CPPFLAGS
Commit 4fafa210 added WARN_CFLAGS, VISIBILITY_HIDDEN_CFLAGS and
-std=gnu99 to AM_CFLAGS in common/Makefile.am, but these are not
needed. WARN_CFLAGS and VISIBILITY_HIDDEN_CFLAGS are not defined
anywhere in spice-common, and spice-common compiles fine without
-std=gnu99 on my f21 box.
diff --git a/common/Makefile.am b/common/Makefile.am
index 19335ce..2c82adc 100644
--- a/common/Makefile.am
+++ b/common/Makefile.am
@@ -97,9 +97,6 @@ AM_CPPFLAGS = \
$(OPUS_CFLAGS) \
$(PROTOCOL_CFLAGS) \
$(SMARTCARD_CFLAGS) \
- $(VISIBILITY_HIDDEN_CFLAGS) \
- $(WARN_CFLAGS) \
- -std=gnu99 \
$(NULL)
libspice_common_la_LIBADD = \
commit ed873a9eb5d3a74557d11e6bea7bcdef09fa2201
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 18:58:19 2014 +0100
build-sys: Remove unused WITH_SMARTCARD conditional
diff --git a/configure.ac b/configure.ac
index e5468b2..8613833 100644
--- a/configure.ac
+++ b/configure.ac
@@ -49,7 +49,6 @@ if test "x$enable_smartcard" != "xno"; then
AC_DEFINE(USE_SMARTCARD, [1], [Define if supporting smartcard proxying])
fi
fi
-AM_CONDITIONAL([WITH_SMARTCARD], [test "x$have_smartcard" = "xyes"])
AC_ARG_ENABLE(celt051,
[ --disable-celt051 Disable celt051 audio codec (enabled by default)],,
commit 2da14b6cc897cc0b960d4efc0e2765dc3f6fba9b
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 11:08:55 2014 +0100
build-sys: Remove unused win32 check
diff --git a/configure.ac b/configure.ac
index e67e60b..e5468b2 100644
--- a/configure.ac
+++ b/configure.ac
@@ -114,21 +114,6 @@ AC_FUNC_ERROR_AT_LINE
AC_FUNC_FORK
AC_CHECK_FUNCS([dup2 floor inet_ntoa memmove memset pow sqrt])
-# Others
-AC_CANONICAL_HOST
-
-AC_MSG_CHECKING([for native Win32])
-case "$host_os" in
- *mingw*|*cygwin*)
- os_win32=yes
- ;;
- *)
- os_win32=no
- ;;
-esac
-AC_MSG_RESULT([$os_win32])
-AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
-
# The End!
AC_CONFIG_FILES([
Makefile
commit 5bfa9cadb3787894ed51241718859c98e3a874e7
Author: Christophe Fergeau <cfergeau at redhat.com>
Date: Tue Dec 2 10:58:10 2014 +0100
build-sys: Remove unused X check
AC_PATH_X sets a bunch of variables (x_includes, x_libraries, no_x)
after finding/not finding X. Since none of them are used afterwards,
having this check is not useful.
diff --git a/configure.ac b/configure.ac
index 273d935..e67e60b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -92,7 +92,6 @@ AC_SUBST(GL_CFLAGS)
AC_SUBST(GL_LIBS)
# Checks for header files
-AC_PATH_X
AC_FUNC_ALLOCA
AC_CHECK_HEADERS([arpa/inet.h malloc.h netinet/in.h stddef.h stdint.h stdlib.h string.h sys/socket.h unistd.h])
More information about the Spice-commits
mailing list