[Spice-devel] [spice-gtk] Use latest warnings.m4 from gnulib

[Christophe Fergeau]

Ping ?

Christophe

On Fri, Sep 27, 2013 at 09:17:55AM +0200, Christophe Fergeau wrote:
> The one we were using does not work properly with clang, causing
> the build process to try to use -f/-W options that are not
> supported by clang.
> ---
> 
> The same patch has already been ACKed and pushed in libvirt-glib/libosinfo/...
> https://www.redhat.com/archives/libvir-list/2013-September/msg01599.html
> 
> Christophe
> 
> 
>  m4/warnings.m4 | 82 ++++++++++++++++++++++++++++++++++++++++++++--------------
>  1 file changed, 62 insertions(+), 20 deletions(-)
> 
> diff --git a/m4/warnings.m4 b/m4/warnings.m4
> index 69d05a6..e3d239b 100644
> --- a/m4/warnings.m4
> +++ b/m4/warnings.m4
> @@ -1,5 +1,5 @@
> -# warnings.m4 serial 5
> -dnl Copyright (C) 2008-2012 Free Software Foundation, Inc.
> +# warnings.m4 serial 11
> +dnl Copyright (C) 2008-2013 Free Software Foundation, Inc.
>  dnl This file is free software; the Free Software Foundation
>  dnl gives unlimited permission to copy and/or distribute it,
>  dnl with or without modifications, as long as this notice is preserved.
> @@ -14,24 +14,66 @@ m4_ifdef([AS_VAR_APPEND],
>  [m4_define([gl_AS_VAR_APPEND],
>  [AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])])
>  
> -# gl_WARN_ADD(PARAMETER, [VARIABLE = WARN_CFLAGS])
> -# ------------------------------------------------
> -# Adds parameter to WARN_CFLAGS if the compiler supports it.  For example,
> -# gl_WARN_ADD([-Wparentheses]).
> -AC_DEFUN([gl_WARN_ADD],
> -dnl FIXME: gl_Warn must be used unquoted until we can assume
> -dnl autoconf 2.64 or newer.
> -[AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_$1])dnl
> -AC_CACHE_CHECK([whether compiler handles $1], m4_defn([gl_Warn]), [
> -  gl_save_CPPFLAGS="$CPPFLAGS"
> -  CPPFLAGS="${CPPFLAGS} $1"
> -  AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])],
> -                    [AS_VAR_SET(gl_Warn, [yes])],
> -                    [AS_VAR_SET(gl_Warn, [no])])
> -  CPPFLAGS="$gl_save_CPPFLAGS"
> +
> +# gl_COMPILER_OPTION_IF(OPTION, [IF-SUPPORTED], [IF-NOT-SUPPORTED],
> +#                       [PROGRAM = AC_LANG_PROGRAM()])
> +# -----------------------------------------------------------------
> +# Check if the compiler supports OPTION when compiling PROGRAM.
> +#
> +# FIXME: gl_Warn must be used unquoted until we can assume Autoconf
> +# 2.64 or newer.
> +AC_DEFUN([gl_COMPILER_OPTION_IF],
> +[AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_[]_AC_LANG_ABBREV[]_$1])dnl
> +AS_VAR_PUSHDEF([gl_Flags], [_AC_LANG_PREFIX[]FLAGS])dnl
> +AS_LITERAL_IF([$1],
> +  [m4_pushdef([gl_Positive], m4_bpatsubst([$1], [^-Wno-], [-W]))],
> +  [gl_positive="$1"
> +case $gl_positive in
> +  -Wno-*) gl_positive=-W`expr "X$gl_positive" : 'X-Wno-\(.*\)'` ;;
> +esac
> +m4_pushdef([gl_Positive], [$gl_positive])])dnl
> +AC_CACHE_CHECK([whether _AC_LANG compiler handles $1], m4_defn([gl_Warn]), [
> +  gl_save_compiler_FLAGS="$gl_Flags"
> +  gl_AS_VAR_APPEND(m4_defn([gl_Flags]),
> +    [" $gl_unknown_warnings_are_errors ]m4_defn([gl_Positive])["])
> +  AC_LINK_IFELSE([m4_default([$4], [AC_LANG_PROGRAM([])])],
> +                 [AS_VAR_SET(gl_Warn, [yes])],
> +                 [AS_VAR_SET(gl_Warn, [no])])
> +  gl_Flags="$gl_save_compiler_FLAGS"
>  ])
> -AS_VAR_IF(gl_Warn, [yes],
> -  [gl_AS_VAR_APPEND(m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]), [" $1"])])
> +AS_VAR_IF(gl_Warn, [yes], [$2], [$3])
> +m4_popdef([gl_Positive])dnl
> +AS_VAR_POPDEF([gl_Flags])dnl
>  AS_VAR_POPDEF([gl_Warn])dnl
> -m4_ifval([$2], [AS_LITERAL_IF([$2], [AC_SUBST([$2])], [])])dnl
>  ])
> +
> +# gl_UNKNOWN_WARNINGS_ARE_ERRORS
> +# ------------------------------
> +# Clang doesn't complain about unknown warning options unless one also
> +# specifies -Wunknown-warning-option -Werror.  Detect this.
> +AC_DEFUN([gl_UNKNOWN_WARNINGS_ARE_ERRORS],
> +[gl_COMPILER_OPTION_IF([-Werror -Wunknown-warning-option],
> +   [gl_unknown_warnings_are_errors='-Wunknown-warning-option -Werror'],
> +   [gl_unknown_warnings_are_errors=])])
> +
> +# gl_WARN_ADD(OPTION, [VARIABLE = WARN_CFLAGS],
> +#             [PROGRAM = AC_LANG_PROGRAM()])
> +# ---------------------------------------------
> +# Adds parameter to WARN_CFLAGS if the compiler supports it when
> +# compiling PROGRAM.  For example, gl_WARN_ADD([-Wparentheses]).
> +#
> +# If VARIABLE is a variable name, AC_SUBST it.
> +AC_DEFUN([gl_WARN_ADD],
> +[AC_REQUIRE([gl_UNKNOWN_WARNINGS_ARE_ERRORS])
> +gl_COMPILER_OPTION_IF([$1],
> +  [gl_AS_VAR_APPEND(m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]), [" $1"])],
> +  [],
> +  [$3])
> +m4_ifval([$2],
> +         [AS_LITERAL_IF([$2], [AC_SUBST([$2])])],
> +         [AC_SUBST([WARN_CFLAGS])])dnl
> +])
> +
> +# Local Variables:
> +# mode: autoconf
> +# End:
> -- 
> 1.8.3.1
> 
> _______________________________________________
> Spice-devel mailing list
> Spice-devel at lists.freedesktop.org
> http://lists.freedesktop.org/mailman/listinfo/spice-devel
-------------- next part --------------
A non-text attachment was scrubbed...
Name: not available
Type: application/pgp-signature
Size: 198 bytes
Desc: not available
URL: <http://lists.freedesktop.org/archives/spice-devel/attachments/20131003/810c011b/attachment.pgp>